Exibir código-fonte para Alunos por curso

/*
- Alunos por curso (ensino médio, fundamental) (exibir ano letivo, curso, turma, disciplina)
*/

USE DES_BLU_GestaoEscolar
GO

; with Dados AS 
(
	SELECT
		Uad.uad_nome AS DRE
		, Esc.esc_nome AS Escola
		, Pes.pes_nome as Aluno
		, Alc.alc_matricula AS [LoginBoletimOnline]
		, Tci.tci_nome AS Ciclo
		, Cur.cur_nome AS Curso
		, Crp.crp_descricao AS Serie
		, Cal.cal_ano AS AnoLetivo
		, Tur.tur_codigo AS Turma
		, CASE Tur.tur_tipo WHEN 1 THEN 'Normal' WHEN 2 THEN 'Recuperação paralela' WHEN 3 THEN 'Educação Física' WHEN 4 THEN 'Educação Física' ELSE '' END AS TipoTurma
		, Tur.tur_id
		, Tur.esc_id
		, ROW_NUMBER() OVER (PARTITION BY Esc.esc_id, Cur.cur_id ORDER BY Alu.alu_id) AS NumeroAlunoCurso
	FROM ACA_Aluno Alu WITH(NOLOCK)
	INNER JOIN MTR_MatriculaTurma Mtu WITH(NOLOCK)
		ON Mtu.alu_id = Alu.alu_id
		AND Mtu.mtu_situacao = 1
	INNER JOIN ACA_AlunoCurriculo Alc WITH(NOLOCK)
		ON Alc.alu_id = Mtu.alu_id
		AND Alc.alc_id = Mtu.alc_id
		AND Alc.alc_situacao = 1
	INNER JOIN TUR_Turma Tur WITH(NOLOCK)
		ON Tur.tur_id = Mtu.tur_id
	INNER JOIN ACA_CalendarioAnual Cal WITH(NOLOCK)
		ON Cal.cal_id = Tur.cal_id
	INNER JOIN ESC_Escola Esc WITH(NOLOCK)
		ON Esc.esc_id = Tur.esc_id
	LEFT JOIN Synonym_SYS_UnidadeAdministrativa Uad WITH(NOLOCK)
		ON Uad.ent_id = Esc.ent_id
		AND Uad.uad_id = Esc.uad_idSuperiorGestao

	INNER JOIN Synonym_PES_Pessoa Pes WITH(NOLOCK)
		ON Pes.pes_id = Alu.pes_id
	LEFT JOIN Synonym_SYS_Usuario Usu WITH(NOLOCK)
		ON Usu.pes_id = Pes.pes_id
		AND Usu.usu_situacao <> 3

	INNER JOIN ACA_Curso Cur WITH(NOLOCK)
		ON Cur.cur_id = Alc.cur_id
	INNER JOIN ACA_CurriculoPeriodo Crp WITH(NOLOCK)
		ON Crp.cur_id = Alc.cur_id
		AND Crp.crr_id = Alc.crr_id
		AND Crp.crp_id = Alc.crp_id
	LEFT JOIN ACA_TipoCiclo Tci WITH(NOLOCK)
		ON Tci.tci_id = Crp.tci_id

	WHERE
		Alu.alu_situacao = 1
		AND Tur.tur_situacao = 1
)
SELECT *
FROM Dados
--WHERE NumeroAlunoCurso <= 20
order by
	DRE
	, Escola
	, Turma
	, Aluno